A new function SafePyEngine was added. It facilitates running python code in Delphi threads.

pyscripter · pyscripter · commit f9be5062c62e · 2023-11-01T01:57:34.000+02:00
diff --git a/Source/PythonEngine.pas b/Source/PythonEngine.pas
@@ -2915,21 +2915,43 @@ function PythonVersionFromRegVersion(const ARegVersion: string;
   out AMajorVersion, AMinorVersion: integer): boolean;
 function PyStatus_Exception(const APyStatus: PyStatus): Boolean;
 
+//#######################################################
+//##                                                   ##
+//##        Support routines for running python        ##
+//##        code in threads                            ##
+//##                                                   ##
+//#######################################################
+
+type
+  IPyEngineAndGIL = interface
+    function GetPyEngine: TPythonEngine;
+    function GetThreadState: PPyThreadState;
+    property PythonEngine: TPythonEngine read GetPyEngine;
+    property ThreadState: PPyThreadState read GetThreadState;
+  end;
+
+// Access the PythonEngine with thread safety
+function SafePyEngine: IPyEngineAndGIL;
+
+
 { Helper functions}
+
 (*
     Checks whether the PythonVersion x.x is Registered
 *)
 {$IFDEF MSWINDOWS}
 function IsPythonVersionRegistered(PythonVersion : string;
   out InstallPath: string; out AllUserInstall: Boolean) : Boolean;
 {$ENDIF}
+
 (*
   Mask FPU Excptions - Useful for importing SciPy and other Python libs
   See http://bugs.python.org/issue9980 and
   http://stackoverflow.com/questions/3933851/
 *)
 procedure MaskFPUExceptions(ExceptionsMasked : boolean;
   MatchPythonPrecision : Boolean = True);
+
 (*
   Converts line breaks to LF and optionally adds a line break at the end
 *)
@@ -9788,5 +9810,53 @@ function PyStatus_Exception(const APyStatus: PyStatus): Boolean;
   Result := APyStatus._type <> _PyStatus_TYPE_OK;
 end;
 
+{ TPyEngineAndGIL - Internal class for SafePythonEngine }
+
+type
+  TPyEngineAndGIL = class(TInterfacedObject, IPyEngineAndGIL)
+  fPythonEngine: TPythonEngine;
+  fThreadState: PPyThreadState;
+  fGILState: PyGILstate_STATE;
+  private
+    function GetPyEngine: TPythonEngine;
+    function GetThreadState: PPyThreadState;
+  public
+    constructor Create;
+    destructor Destroy; override;
+  end;
+
+
+constructor TPyEngineAndGIL.Create;
+begin
+  inherited Create;
+  fPythonEngine := GetPythonEngine;
+  fGILState := fPythonEngine.PyGILState_Ensure;
+  fThreadState := fPythonEngine.PyThreadState_Get;
+end;
+
+destructor TPyEngineAndGIL.Destroy;
+begin
+  fPythonEngine.PyGILState_Release(fGILState);
+  inherited;
+end;
+
+function TPyEngineAndGIL.GetPyEngine: TPythonEngine;
+begin
+  Result := fPythonEngine;
+end;
+
+function TPyEngineAndGIL.GetThreadState: PPyThreadState;
+begin
+  Result := fThreadState;
+end;
+
+{ SafePythonEngine }
+function SafePyEngine: IPyEngineAndGIL;
+begin
+  Result := TPyEngineAndGIL.Create
+end;
+
+
+
 end.
 
