20000124: Unidata McIDAS-X/760 install

>From: "Loftus, Maryellen E." <address@hidden>
>Organization: TASC
>Keywords: 200001242158.OAA16040 McIDAS-X install

Mary Ellen,

>We just downloaded unidata mcidas version7.6 to be run on our IBM
>RS6000 using AIX.  We currently have SSEC version 7.6 running on this
>machine.  I downloaded the software into a unique directory
>/home/mcidas/unidata/ as to avoid any interactions with the SSEC
>version when we install.

Sounds good so far.

>We would like the ability to run both the SSEC version and the Unidata
>version in parallell.  We are hesitant to "install" until we understand
>what if any ramifications there will be if we blindly go ahead at this
>point.

If the parallel install is done correctly, there should be no interaction
between the two distributions.

>Do we need to set any mcidas paths before we install?

As with the generic SSEC distribution, you need to set the environment
variable McINST_ROOT to be the top level directory under which you want
to install the package.  Since you have already chosen /home/mcidas/unidata
as the directory under which the source distribution is to be unpacked,
and since your SSEC distribution is most likely installed under /home/mcidas,
I suggest that for the Unidata distribution you set McINST_ROOT to be
/home/mcidas/uni760.  Whatever you do, DO NOT set McINST_ROOT to be
/home/mcidas/unidata!

>Are the same
>environment variables used in the SSEC version used by the Unidata
>version?

Yes except that I instruct my users to define two additional environment
variables for Unidata McIDAS-X: MCDATA, and MCGUI.

By the way, I remove the SSEC restriction that McIDAS can not be run
from the 'mcidas' account.

In my distribution, each McIDAS-X user will have a McIDAS working
directory that is defined by the environment variable MCDATA.  My
McIDAS startup script CDs the user to this directory at startup.  This
directory must also be the first directory in that user's MCPATH.
For the user 'mcidas', this directory is typically ~mcidas/workdata;
for other users, the directory is typically ~user/mcidas/data.

MCGUI is defined to be the directory in which Unidata McIDAS-X
executables are installed.  This directory is typically ~mcidas/bin.

In addition, if you are using the C shell, then you need to put a
conditional construct around the setting of the MCDATA, MCPATH, and
MCGUI environment variables.  I illustrate this below.

>It seems as if we should have two coexisiting profiles and
>when the mcidas command is run, it should source the appropriate
>version.  How would we set this up if necessary?

It is necessary, and this is how I go about the same kind of thing here.

I maintain installations for multiple arcitectures (e.g., AIX, Sun
Solaris SPARC, Sun Solaris Intel, Digital Unix, Linux, HP-UX, IRIX) in
the same /home/mcidas directory structure.  Here is basically how this
looks on my system:

                      /home/mcidas
        ---------------------------------------------
       /      /         /       \        \     \     \
      aix  solaris  solarisx86  alpha  linux  hpux  irix

Each platform specific directory has the typical McIDAS installation directories
under it and one additional directory:

bin/      - Unidata McIDAS-X executables
data/     - Unidata McIDAS-X ancillary data files (e.g. map databases,
            enhancements, stretch tables, etc.)
help/     - Unidata McIDAS-X help files
inc/      - Unidata McIDAS-X include files
lib/      - Unidata McIDAS-X libraries
man/      - Unidata McIDAS-X man pages
tcl/      - Unidata McIDAS-X Tcl/Tk stuff
workdata/ - Unidata McIDAS-X working directory for the user 'mcidas'

I keep the environment for each platform separate by maintaining
separate cshrc.<platform> files for each (I use the C shell).  My
.cshrc file will then source the cshrc.<platform> that is called for by
the operating system I am logged into (e.g., cshrc.linux for Linux,
cshrc.alpha for Digital Unix, etc.).  The selection code in my .cshrc
file that does this looks like:

# Set operating system name and release

setenv OS      `uname -s`
setenv RELEASE `uname -r`

switch ($OS)
case SunOS:
    switch ($RELEASE)
    case 4*:
        source $HOME/cshrc.sunos
        breaksw
    case 5*:
        switch (`uname -m`)
        case sun*:
            source $HOME/cshrc.solaris
            breaksw
        case i86pc:
            source $HOME/cshrc.solarisx86
            breaksw
        default:
            echo Unknown Solaris platform
            exit
        endsw
        breaksw
    default:
        echo Unknown SunOS version
        exit
    endsw
    breaksw
case IRIX:
    source $HOME/cshrc.sgi
    breaksw
case IRIX64:
    source $HOME/cshrc.sgi64
    breaksw
case AIX:
    source $HOME/cshrc.aix
    breaksw
case HP-UX:
    source $HOME/cshrc.hpux
    breaksw
case OSF1:
    source $HOME/cshrc.alpha
    breaksw
case Linux:
    source $HOME/cshrc.linux
    breaksw
endsw


My platform specific cshrc.<platform> file will then look something like
(snippit is from the cshrc.alpha file for Digital Unix):

umask 002

if ( ! ${?MCPATH} ) then
setenv MCDATA $HOME/alpha/workdata
setenv MCPATH ${MCDATA}:$HOME/alpha/data:$HOME/alpha/help
setenv MCGUI  $HOME/alpha/bin
endif

setenv McINST_ROOT /home/mcidas/alpha
setenv XCD_disp_file $MCDATA/DECOSTAT.DAT

and so on.

For your setup, I would recommend you create a ~mcidas/cshrc.unidata file
that contains:

umask 002

if ( ! ${?MCPATH} ) then
setenv MCDATA $HOME/uni760/workdata
setenv MCPATH ${MCDATA}:$HOME/uni760/data:$HOME/uni760/help
setenv MCGUI  $HOME/uni760/bin
endif

setenv McINST_ROOT /home/mcidas/unidata
setenv PATH ${MCGUI}:.:$PATH

etc.  (Notice how the directory tree containing the source distribution
is different from the installation tree!)

For you to run the Unidata distribution of McIDAS as the user 'mcidas',
you would have to do the following:

unsetenv MCPATH                    (so that the conditional in cshrc.unidata
                                    does not come into play)
source ~/cshrc.alpha               (assuming you were working on Digital Unix)

At this point, you should verify your environemt by doing things like:

which mcidas

This should be the one in /home/mcidas/uni760/bin.

>Thanks for any help you can provide.

You are welcome.  Please don't hesitate to ask for more details if the
above doesn't make sense.  For further information on how I instruct my
users on installing Unidata McIDAS, please refer to:

Unidata Homepage
http://www.unidata.ucar.edu
  Unidata McIDAS
  http://www.unidata.ucar.edu/packages/mcidas
    Unidata McIDAS-X
    http://www.unidata.ucar.edu/packages/mcidas/mcx
      Installation
      http://www.unidata.ucar.edu/packages/mcidas/mcx/mcidas-x.html
    
>Mary Ellen Loftus
>TASC  -- MTS
>4801 Stonecroft Blvd
>Chantilly, VA 20151

Tom Yoksas